devbox
正经夜光杯
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

ARM-Cortex A9异常处理流程_cortex-a9 cpsr

作者：正经夜光杯 | 2024-08-13 06:11:41

赞

踩

cortex-a9 cpsr

第一部分

一. 异常的概念

处理器在正常执行程序的过程中可能会遇到一些不正常的事件发生

    这时处理器就要将当前的程序暂停下来转而去处理这个异常的事件

    异常事件处理完成之后再返回到被异常打断的点继续执行程序

二. 异常处理机制

异常处理机制

    不同的处理器对异常的处理的流程大体相似，但是不同的处理器在具体实现的机制上有所不同；比如处理器遇到哪些事件认为是异常事件遇到异常事件之后处理器有哪些动作、处理器如何跳转到异常处理程序如何处理异常、处理完异常之后又如何返回到被打断的程序继续执行等我们将这些细节的实现称为处理器的异常处理机制

三. ARM异常源

概念

    导致异常产生的事件称为异常源

 ARM异常源

    FIQ                                快速中断请求引脚有效                

    IRQ                                外部中断请求引脚有效

    Reset                        复位电平有效

    Software Interrupt        执行swi指令

    Data Abort                        数据终止

    Prefetch Abort                指令预取终止

    Undefined Instruction        遇到不能处理的指令

四. ARM异常模式

异常模式

    在ARM的基本工作模式中有5个属于异常模式，即ARM遇到异常后会切

换成对应的异常模式

五. ARM异常响应

ARM产生异常后的动作（自动完成）

    1.拷贝CPSR中的内容到对应异常模式下的SPSR_<mode>

    2.修改CPSR的值

2.1.修改中断禁止位禁止相应的中断

2.2.修改模式位进入相应的异常模式     产生异常

            2.3.修改状态位进入ARM状态

    3.保存返回地址到对应异常模式下的LR_<mode>

    4.设置PC为相应的异常向量（异常向量表对应的地址）

六. 异常向量表

异常向量表

    > 异常向量表的本质是内存中的一段代码

    > 表中为每个异常源分配了四个字节的存储空间

    > 遇到异常后处理器自动将PC修改为对应的地址

    > 因为异常向量表空间有限一般我们不会再这里

      写异常处理程序，而是在对应的位置写一条跳

      转指令使其跳转到指定的异常处理程序的入口

    注：ARM的异常向量表的基地址默认在0x00地址

        但可以通过配置协处理器来修改其地址

七. 异常返回

 ARM异常返回的动作（自己编写）

    1.将SPSR_<mode>的值复制给CPSR

      使处理器恢复之前的状态

    2.将LR_<mode>的值复制给PC

      使程序跳转回被打断的地址继续执行

八. IRQ异常举例

注：整个过程CPSR保存的永远是当前程序运行状态 , SPSR只是异常时对原来的CPSR进行备份

CPSR:当前程序状态寄存器

第二部分：中断代码执行流程分析

一. 启动代码的分析

1. 实验思路

2. 程序源码

2. 1启动文件
  1. .text
  2. .global _start
  3. _start:
  4. 	/*
  5. 	 * Vector table  异常向量表
  6. 	 */ 
  7. 	b reset
  8. 	b .
  9. 	b .
  10. 	b .
  11. 	b .
  12. 	b .
  13. 	/*
  14. 	 * 从异常向量表再跳转到IRQ的异常处理程序
  15. 	 */
  16. 	b irq_handler
  17. 	b .
  18.  
  19. reset:
  20. 	/*
  21. 	 * Set vector address in CP15 VBAR register
  22. 	 */ 
  23. 	ldr	r0, =_start
  24. 	mcr	p15, 0, r0, c12, c0, 0	@Set VBAR
  25.  
  26. 	/*
  27. 	 * Set the cpu to SVC32 mode, Disable FIQ/IRQ
  28. 	 */  
  29. 	mrs r0, cpsr
  30. 	bic r0, r0, #0x1f
  31. 	orr	r0, r0, #0xd3
  32. 	msr	cpsr ,r0
  33.  
  34. 	/*
  35. 	 * Defines access permissions for each coprocessor
  36. 	 */  
  37.     mov	r0, #0xfffffff
  38.     mcr	p15, 0, r0, c1, c0, 2  	
  39.  
  40. 	/*
  41. 	 * Invalidate L1 I/D                                                                                                                   
  42. 	 */
  43. 	mov	r0, #0					@Set up for MCR
  44. 	mcr	p15, 0, r0, c8, c7, 0	@Invalidate TLBs
  45. 	mcr	p15, 0, r0, c7, c5, 0	@Invalidate icache
  46. 	
  47. 	/*
  48. 	 * Set the FPEXC EN bit to enable the FPU
  49. 	 */ 
  50. 	mov r3, #0x40000000
  51. 	fmxr FPEXC, r3
  52. 	
  53. 	/*
  54. 	 * Disable MMU stuff and caches
  55. 	 */
  56. 	mrc	p15, 0, r0, c1, c0, 0
  57. 	bic	r0, r0, #0x00002000		@Clear bits 13 (--V-)
  58. 	bic	r0, r0, #0x00000007		@Clear bits 2:0 (-CAM)
  59. 	orr	r0, r0, #0x00001000		@Set bit 12 (---I) Icache
  60. 	orr	r0, r0, #0x00000002		@Set bit 1 (--A-) Align
  61. 	orr	r0, r0, #0x00000800		@Set bit 11 (Z---) BTB
  62. 	mcr	p15, 0, r0, c1, c0, 0
  63.  
  64. 	/*
  65. 	 * Initialize stacks                                                                                                                  
  66. 	 */
  67. init_stack:     
  68. 	/*svc mode stack*/
  69. 	msr cpsr, #0xd3
  70. 	ldr sp, _stack_svc_end
  71.  
  72. 	/*undef mode stack*/
  73. 	msr cpsr, #0xdb
  74. 	ldr sp, _stack_und_end
  75.  
  76. 	/*abort mode stack*/	
  77. 	msr cpsr,#0xd7
  78. 	ldr sp,_stack_abt_end
  79.  
  80. 	/*irq mode stack*/	
  81. 	msr cpsr,#0xd2
  82. 	ldr sp, _stack_irq_end
  83. 	
  84. 	/*fiq mode stack*/
  85. 	msr cpsr,#0xd1
  86. 	ldr sp, _stack_fiq_end
  87. 	
  88. 	/*user mode stack, enable FIQ/IRQ*/
  89. 	msr cpsr,#0x10
  90. 	ldr sp, _stack_usr_end
  91.  
  92. 	/*Call main*/
  93. 	b main
  94.  
  95. 	/*
  96. 	 * IRQ的异常处理程序
  97. 	 */
  98. irq_handler:
  99. 	/*
  100. 	 * 因为产生IRQ异常后ARM自动保存到LR中的返回地址是被IRQ打断的指令
  101.      * 的下一条再下一条指令的地址，所以我们需要人为的去修正一下
  102. 	 */
  103. 	sub lr, lr, #4
  104. 	/*
  105. 	 * 因为IRQ模式下使用的R0-R12寄存器和USER模式下使用的是同一组
  106. 	 * 所以在处理异常之前需要先将之前寄存器中的值压栈保护
  107. 	 */
  108. 	stmfd sp!, {r0-r12,lr}
  109. 	/*
  110. 	 * 跳转到do_irq处理异常
  111. 	 */
  112. 	bl do_irq
  113. 	/*
  114. 	 * 异常返回
  115. 	 * 1.将R0-R12寄存器中的值出栈，使其恢复到被异常打断之前的值
  116. 	 * 2.将SPSR寄存器中的值恢复到CPSR，使CPU的状态恢复到被异常打断之前
  117. 	 * 3.将栈中保存的LR寄存器的值出栈给PC，使程序跳转回被异常打断的点继续执行
  118. 	 */
  119. 	ldmfd sp!,{r0-r12,pc}^  // '^'意思是自动将SPSR中的值赋值给
  120.  
  121. _stack_svc_end:      
  122. 	.word stack_svc + 512
  123. _stack_und_end:      
  124. 	.word stack_und + 512
  125. _stack_abt_end:      
  126. 	.word stack_abt + 512
  127. _stack_irq_end:      
  128.     .word stack_irq + 512
  129. _stack_fiq_end:
  130.     .word stack_fiq + 512
  131. _stack_usr_end:      
  132.     .word stack_usr + 512
  133.  
  134. .data
  135. stack_svc:      
  136. 	.space 512
  137. stack_und:
  138. 	.space 512
  139. stack_abt:      
  140. 	.space 512
  141. stack_irq:      
  142. 	.space 512
  143. stack_fiq:      
  144. 	.space 512
  145. stack_usr:      
  146. 	.space 512
 2.2用户文件
  1. #include "exynos_4412.h"
  2.  
  3. unsigned int Flags = 0;
  4.  
  5. void Delay(unsigned int Time)
  6. {
  7. 	while(Time--);
  8. }
  9.  
  10. //IRQ异常处理
  11. void do_irq(void)
  12. {
  13. 	unsigned int IrqNum = 0;
  14. 	/*从中断控制器中获取当前中断的中断号*/
  15. 	IrqNum = CPU0.ICCIAR & 0x3FF;
  16. 	
  17. 	/*根据中断号处理不同的中断*/
  18. 	switch(IrqNum)
  19. 	{
  20. 		case 0:
  21. 			//0号中断的处理程序
  22. 			break;
  23. 		case 1:
  24. 			//1号中断的处理程序
  25. 			break;
  26. 			/*
  27. 			 * ... ...
  28. 			 */
  29. 		case 58:    //[EINT 10]
  30. 			Delay(1000000);
  31. 			Flags++;
  32. 			printf("key3 pressed.\n");
  33. 			/*清除GPIO控制器中GPX1_2的中断挂起标志位*/
  34. 			EXT_INT41_PEND = (1 << 2);
  35. 			/*将当前中断的中断号写回到中断控制器中，以这种方式来告知中断控制器当前的中断已经处理完成，可以发送其它中断*/
  36. 			CPU0.ICCEOIR = CPU0.ICCEOIR & (~(0x3FF)) | (58);
  37. 			break;
  38. 			/*
  39. 			 * ... ...
  40. 			 */
  41. 		case 159:
  42. 			//159号中断的处理程序
  43. 			break;
  44. 		default:
  45. 			break;
  46. 		
  47. 	}
  48.  
  49. }
  50.  
  51. void LED2_ON() {
  52. 	GPX2.DAT = GPX2.DAT | (1 << 7);
  53. }
  54.  
  55. void LED2_OFF() {
  56. 	GPX2.DAT = GPX2.DAT & (~(1 << 7));
  57. }
  58.  
  59. int main()
  60. {
  61.  
  62. 	/******************************/
  63. 	//初始化
  64. 	/******************************/
  65. 	/*外设层次 - 让外部的硬件控制器产生一个中断信号发送给中断控制器*/
  66. 	/*将GPX1_1设置成中断功能*/
  67. 	GPX1.CON = GPX1.CON | (0xF << 8);
  68. 	/*设置GPX1_1的中断触发方式为下降沿触发*/
  69. 	EXT_INT41_CON = EXT_INT41_CON & (~(0x7 << 8)) | (0x2 << 8);
  70. 	
  71. 	/*使能GPX1_2的中断功能*/
  72. 	EXT_INT41_MASK = EXT_INT41_MASK & (~(1 << 2));
  73.  
  74.  
  75.  
  76. 	/******************************/
  77. 	//中断控制器层次
  78. 	/******************************/
  79. 	/*中断控制器层次 - 让中断控制器接收外设产生的中断信号并对其进行管理然后再转发给CPU处理*/
  80. 	/*全局使能中断控制器使其能接收外设产生的中断信号并转发到CPU接口*/
  81. 	ICDDCR = ICDDCR | 1;
  82.  
  83. 	/*在中断控制器中使能57号中断，使中断控制器接收到57号中断后能将其转发到CPU接口*/
  84. 	ICDISER.ICDISER1 = ICDISER.ICDISER1 | (1 << 26);
  85. 	/*选择由CPU0来处理57号中断*/
  86. 	ICDIPTR.ICDIPTR14 = ICDIPTR.ICDIPTR14 & (~(0xFF << 16)) | (0X01 << 16);
  87.  
  88. 	/*使能中断控制器和CPU0之间的接口，使中断控制器转发的中断信号能够到达CPU0*/
  89. 	CPU0.ICCICR = CPU0.ICCICR | 1;
  90.  
  91. 	/*初始化GPX2_7为输出功能 为LED2做准备*/
  92. 	GPX2.CON = GPX2.CON & (~(0xF << 28)) | (0x1 << 28);
  93.  
  94.     while(1)
  95. 	{   
  96. 		switch(Flags % 2) {
  97. 		case 0:
  98. 			LED2_ON();
  99. 			printf("LED2_ON\n");
  100. 			Delay(1000000);
  101. 			break;
  102. 		case 1:
  103. 			LED2_OFF();
  104. 			printf("LED2_OFF\n");
  105. 			Delay(1000000);
  106. 			break;
  107. 		}
  108. 	}   
  109.  
  110. 	return 0;
  111. }

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/正经夜光杯/article/detail/973569
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号