devbox
正经夜光杯
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

FPGA项目实战 — 串口接收、RAM存储、RGB接口TFT显示_fpga数据显示

作者：正经夜光杯 | 2024-08-13 10:03:32

赞

踩

fpga数据显示

参考文章：https://www.cnblogs.com/fbur/p/16518333.html

源码下载：GitHub - Redamancy785/FPGA-Learning-Record: 项目博客：https://blog.csdn.net/weixin_51460407

代码功能

        本案例通过串口调试上位机将一张256×256照片的十六进制文本发送至开发板串口，接着开发板通过串口将数据存储入RAM中，最后从RAM读取数据并显示在屏幕上。

开发平台

开发板：小梅哥ACZ7015开发板+拓展板+800×640RGB-TFT屏幕

串口调试上位机：友善调试助手

图片生成十六进制文本工具：Img2Lcd

资源下载

链接：https://pan.baidu.com/s/147E_xyWExGrXG_0qOAeLsQ?pwd=ydgb 
 

一、系统架构

 局部放大

        模块间的互联逻辑

        uart_receive模块负责遵守urat协议接收上位机发送的数据并传送给uart_to_ram模块，uart_to_ram模块将接收的八位并行数据打包为十六位并行数据并传送给rom_image模块，rom_image模块负责存储接收的数据。以上是数据写入逻辑。

        disp_driver模块实时输出屏幕将要显示的坐标以向image_extract模块索要该坐标的的图像数据，从而在接收到数据之后驱动屏幕。所以，image_extract模块是一个“控制什么位置输出什么数据”的模块，当判断到该坐标需要使用RAM中的数据时，会向rom_image模块索要数据。以上是数据读出逻辑。

二、顶层模块

  1. module rom_image_tft_hdmi(
  2.     clk50M,
  3.     reset_n,
  4.     uart_tx,
  5. 	TFT_rgb,
  6. 	TFT_hs,
  7. 	TFT_vs,
  8. 	TFT_clk,
  9. 	TFT_de,
  10. 	TFT_pwm,
  11. 	
  12. 	//HDMI
  13. 	SiI9022_sclk,
  14. 	SiI9022_sdat,
  15. 	led     	
  16. );
  17.  
  18.     input         clk50M;   //系统时钟输入，50M
  19.     input         reset_n;  //复位信号输入，低有效 
  20.     input         uart_tx ; //串口接受接口  
  21.     output [15:0] TFT_rgb;  //TFT数据输出
  22.     output        TFT_hs;   //TFT行同步信号
  23.     output        TFT_vs;   //TFT场同步信号
  24.     output        TFT_clk;  //TFT像素时钟
  25.     output        TFT_de;   //TFT数据使能
  26.     output        TFT_pwm;  //TFT背光控制
  27.     
  28.     inout         SiI9022_sdat;
  29.     output        SiI9022_sclk;
  30.     output        led;
  31.     
  32. /参数/
  33.     //设置待显示图片尺寸，和存储图片ROM的地址位宽，显示背景颜色
  34.     parameter DISP_IMAGE_W    = 256;
  35.     parameter DISP_IMAGE_H    = 256;
  36.     parameter ROM_ADDR_WIDTH  = 16; 
  37.     parameter DISP_BACK_COLOR = 16'hFFFF; //白色
  38.     
  39.     //设置屏幕尺寸
  40.     parameter TFT_WIDTH  = 800;
  41.     parameter TFT_HEIGHT = 480;
  42.     
  43.     //图片显示在屏幕中间位置
  44.     parameter DISP_HBEGIN = (TFT_WIDTH  - DISP_IMAGE_W)/2;
  45.     parameter DISP_VBEGIN = (TFT_HEIGHT - DISP_IMAGE_H)/2;
  46.     
  47. /网表型/
  49. 寄存器型/
  53. 时序逻辑/   
  54.      
  55.     //pll模块
  56.     wire                      pll_locked;
  57.     wire loc_clk33M;
  58.     pll pll(
  59.         .clk_out1(loc_clk33M ), // output clk_out1
  60.         .resetn  (reset_n     ), // input reset,active low
  61.         .locked  (pll_locked  ), // output locked
  62.         .clk_in1 (clk50M      )  // input clk_in1
  63.     ); 
  65.     //uart接收模块
  66.     wire [7:0]parallel_data ;//串口接收模块接收的并行数据8位
  67.     wire rx_done ;//串口接收模块接收8位数据结束信号
  68.  
  69.     uart_receive_1 uart_receive(//串口接收模块
  70.         .clk(clk50M) ,
  71.         .reset(reset_n) ,
  72.         .baud_rate(5) ,
  73.         .uart_tx(uart_tx), 
  74.         .data(parallel_data) ,
  75.         .rx_done(rx_done)   
  76.     );  
  77.   
  78.     //uart_to_ram模块
  79.     wire [15:0]addr_write ;//串口接收模块接收的并行数据8位
  80.     wire [15:0]data_write ;//串口接收模块接收8位数据结束信号
  81.     wire write_enable ;//写入使能信号
  82.     
  83.     uart_to_ram uart_to_ram(//将uart串口接收模块输出的数据写入ram中
  84.         .clk(clk50M) ,
  85.         .reset(reset_n) ,
  86.         .data(parallel_data),
  87.         .rx_done(rx_done),
  88.         .addr(addr_write) ,
  89.         .dout(data_write) ,
  90.         .wenable(write_enable )    
  91.     ); 
  92.       
  93.     //rom_image模块
  94.     wire [ROM_ADDR_WIDTH-1:0] rom_addra;
  95.     wire [15:0]               rom_data;
  96.     
  97.         rom_image rom_image (
  98.         .clka(clk50M),    // input wire clka
  99.         .ena(1),      // input wire ena
  100.         .wea(write_enable),      // input wire [0 : 0] wea
  101.         .addra(addr_write),  // input wire [15 : 0] addra
  102.         .dina(data_write),    // input wire [15 : 0] dina
  103.         .clkb(loc_clk33M),    // input wire clkb
  104.         .addrb(rom_addra),  // input wire [15 : 0] addrb
  105.         .doutb(rom_data)  // output wire [15 : 0] doutb
  106.     );
  108.     //image_extract模块
  109.     wire [15:0]               disp_data;
  110.     wire                      disp_data_req;
  111.     wire [11:0]               visible_hcount;
  112.     wire [11:0]               visible_vcount;
  113.     wire Frame_Begin;
  114.     image_extract#(
  115.         .H_Visible_area (TFT_WIDTH      ), //屏幕显示区域宽度
  116.         .V_Visible_area (TFT_HEIGHT     ), //屏幕显示区域高度
  117.         .IMG_WIDTH      (DISP_IMAGE_W   ), //图片宽度
  118.         .IMG_HEIGHT     (DISP_IMAGE_W   ), //图片高度
  119.         .IMG_DATA_WIDTH (16             ), //图片像素点位宽
  120.         .ROM_ADDR_WIDTH (ROM_ADDR_WIDTH )  //存储图片ROM的地址位宽
  121.     )
  122.     image_extract(
  123.         .clk_ctrl       (loc_clk33M       ),
  124.         .reset_n        (pll_locked    ),
  125.         .img_disp_hbegin(DISP_HBEGIN    ),
  126.         .img_disp_vbegin(DISP_VBEGIN    ),
  127.         .disp_back_color(DISP_BACK_COLOR),
  128.         .rom_addra      (rom_addra      ),
  129.         .rom_data       (rom_data       ),
  130.         .Frame_Begin    (Frame_Begin    ),
  131.         .disp_data_req  (disp_data_req  ),
  132.         .visible_hcount (visible_hcount ),
  133.         .visible_vcount (visible_vcount ),
  134.         .disp_data      (disp_data      )
  135.     );
  136.     
  137.     //disp_driver模块
  138.     wire tft_reset_p;
  139.     wire [4:0]Disp_Red;
  140.     wire [5:0]Disp_Green;
  141.     wire [4:0]Disp_Blue;
  142.     wire [15:0]TFT_rgb;
  143.      
  144.     disp_driver disp_driver(
  145.         .ClkDisp(loc_clk33M),
  146.         .Rst_p(tft_reset_p),
  147.         .Data(disp_data),
  148.         .DataReq(disp_data_req), 
  149.         .H_Addr(visible_hcount),
  150.         .V_Addr(visible_vcount),                   
  151.         .Disp_HS(TFT_hs),
  152.         .Disp_VS(TFT_vs),
  153.         .Disp_Red(Disp_Red),
  154.         .Disp_Green(Disp_Green),
  155.         .Disp_Blue(Disp_Blue),
  156.         .Frame_Begin(Frame_Begin),                   
  157.         .Disp_DE(TFT_de),
  158.         .Disp_PCLK(TFT_clk)
  159.     );
  160.     
  161.     
  162. /组合逻辑/   
  163.     assign tft_reset_p = ~pll_locked; //锁相环提供的TFT屏复位信号进行取反，满足高电平复位	
  164.     assign TFT_rgb={Disp_Red,Disp_Green,Disp_Blue};
  165.     assign TFT_pwm=1'b1;
  166. 	
  167. 	
  168.     /*
  169.     //HDMI模块
  170.     reg [20:0]cnt;
  171.     reg Go;
  172.     
  173.     always@(posedge clk50M or negedge reset_n)
  174.     if(!reset_n)
  175.         cnt <= 0;
  176.     else if(cnt <= 499999)
  177.         cnt <= cnt + 1 ;
  178.     else
  179.         cnt <= 500001;    
  180.         
  181.     always@(posedge clk50M or negedge reset_n)
  182.     if(!reset_n)
  183.         Go <= 0;
  184.     else if(cnt == 499999)
  185.         Go <= 1'b1;
  186.     else
  187.         Go <= 0;
  188.     
  189.     SiI9022_Init SiI9022_Init(
  190.         .Clk(clk50M),
  191.         .Rst_n(reset_n),
  192.         
  193.         .Go(Go),
  194.         .device_id(8'h72),
  195.         .Init_Done(led),
  196.         
  197.         .i2c_sclk(SiI9022_sclk),
  198.         .i2c_sdat(SiI9022_sdat)
  199.     );
  200.     */
  201.  
  202. endmodule

三、uart_receive模块

  1. module uart_receive_1(
  2.     clk ,
  3.     reset ,
  4.     baud_rate ,
  5.     uart_tx, 
  6.     data ,
  7.     rx_done   
  8.     );
  9.     input  clk ;
  10.     input reset ;
  11.     input [2:0]baud_rate ;
  12.     input uart_tx ;
  13.     output reg [7:0]data ;
  14.     output reg rx_done ;
  15.     
  16.     reg rx_done_sig ;
  17.     reg [2:0]r_data[7:0] ;//接收每一位数据
  18.     reg [2:0]sta_bit ;
  19.     reg [2:0]sto_bit ;
  20.     reg [17:0]bit_tim ;//每一位持续的时间（计数）
  21.     
  22.     always@(baud_rate)  //在这里一个 码元由一位组成，所以波特率=比特率
  23.         begin
  24.             case(baud_rate)         //常见的串口传输波特率
  25.             3'd0 : bit_tim = 1000000000/300/20 ; //波特率为300
  26.             3'd1 : bit_tim = 1000000000/1200/20 ; //波特率为1200
  27.             3'd2 : bit_tim = 1000000000/2400/20 ; //波特率为2400
  28.             3'd3 : bit_tim = 1000000000/9600/20 ; //波特率为9600
  29.             3'd4 : bit_tim = 1000000000/19200/20 ; //波特率为19200
  30.             3'd5 : bit_tim = 1000000000/115200/20 ; //波特率为115200
  31.             default bit_tim = 1000000000/9600/20 ;   //多余的寄存器位置放什么：默认速率
  32.             endcase
  33.      end
  34.     
  35.     wire [17:0]bit_tim_16 ;//每1/16位的持续时间（计数）
  36.     assign bit_tim_16 = bit_tim / 16;
  37.     
  38.     wire [8:0]bit16_mid ; //在中心点产生采样脉冲 
  39.     assign bit16_mid = bit_tim_16 / 2 ;
  40.     
  41.     //边沿检测
  42.     reg [1:0]edge_detect ;
  43.     always @( posedge clk or negedge reset )
  44.     begin
  45.         if (!reset )
  46.             edge_detect <= 2'd0 ;
  47.         else 
  48.             begin
  49.             edge_detect[0] <= uart_tx ;
  50.             edge_detect[1] <= edge_detect[0] ;
  51.             end
  52.     end    
  54.     wire byte_sta_neg ;
  55.     assign byte_sta_neg = ( edge_detect == 2'b10 ) ? 1 : 0 ;//输入的数据开始出现下降沿，说明出现了起始位（一直运行？）
  56.          
  57.     reg receive_en ;//接收使能端
  58.     reg [17:0]div_cnt ;//每1/16bit内的计数
  59.      reg [7:0]bit16_cnt ;//计数到了第几个状态（10位，每位分成16份，总共160个状态）
  60.     always @( posedge clk or negedge reset )
  61.     begin
  62.          if (!reset )
  63.             receive_en <= 1'd0 ;
  64.         else if ( byte_sta_neg )    //检测到下降沿，使能段有效（只要有下降沿就使能？）
  65.             receive_en <= 1'd1 ;
  66.         else if ( (rx_done) || (sta_bit >= 3'd4 ))    
  67.             receive_en <= 1'd0 ;    //检测到结束信号，使能端无效
  68.         else if ( ( bit16_cnt == 8'd159 ) && (div_cnt == bit_tim_16 - 1'd1 ) )//跑完159后re_en置零
  69.             receive_en <= 1'd0 ;
  70.     end
  71.              
  72.     
  73.     always@( posedge clk or negedge reset )
  74.     begin
  75.         if ( ! reset )
  76.             div_cnt <= 18'd0 ;
  77.         else if (receive_en)
  78.         begin
  79.             if ( div_cnt == bit_tim_16 - 1'd1 )//计数，每1/16bit清零
  80.                 div_cnt <= 18'd0 ;               
  81.             else
  82.                 div_cnt <= div_cnt + 1'b1 ; 
  83.         end
  84.         else 
  85.             div_cnt <= 18'd0 ;
  86.     end
  87.     
  88.     reg bit16_pulse ;//产生采样脉冲
  89.     always@( posedge clk or negedge reset )
  90.     begin
  91.         if ( ! reset )
  92.             bit16_pulse <= 18'd0 ;
  93.         else if (receive_en)
  94.             if ( div_cnt == bit16_mid )
  95.                 bit16_pulse <= 1'd1 ;
  96.             else
  97.                 bit16_pulse <= 1'd0 ;
  98.         else
  99.                 bit16_pulse <= 1'd0 ;                
  100.     end       
  101.    
  102.     always@( posedge clk or negedge reset )
  103.     begin
  104.         if ( ! reset )
  105.             bit16_cnt <= 8'd0 ;
  106.         else if (receive_en)
  107.         begin    
  108.             if (( bit16_cnt == 8'd159 ) && (div_cnt == bit_tim_16 - 1'd1 ))
  109.                 bit16_cnt <= 8'd0 ;
  110.             else if ( div_cnt == bit_tim_16 - 1'd1 )
  111.                 bit16_cnt <= bit16_cnt + 1'b1 ;
  112.         end
  113.     end
  114.       
  115.     always@(posedge clk or negedge reset)
  116.     begin
  117.     if(!reset)
  118.     begin
  119.         sta_bit   <= 3'd0 ;
  120.         r_data[0] <= 3'd0 ;
  121.         r_data[1] <= 3'd0 ;
  122.         r_data[2] <= 3'd0 ;
  123.         r_data[3] <= 3'd0 ;
  124.         r_data[4] <= 3'd0 ;
  125.         r_data[5] <= 3'd0 ;
  126.         r_data[6] <= 3'd0 ;
  127.         r_data[7] <= 3'd0 ;
  128.         sto_bit   <= 3'd0 ;
  129.     end
  130.     else if (bit16_pulse)//舍弃前5后4取中7
  131.         case(bit16_cnt)
  132.             0: 
  133.             begin 
  134.             sta_bit   <= 3'd0 ;
  135.             r_data[0] <= 3'd0 ;
  136.             r_data[1] <= 3'd0 ;
  137.             r_data[2] <= 3'd0 ;
  138.             r_data[3] <= 3'd0 ;
  139.             r_data[4] <= 3'd0 ;
  140.             r_data[5] <= 3'd0 ;
  141.             r_data[6] <= 3'd0 ;
  142.             r_data[7] <= 3'd0 ;
  143.             sto_bit   <= 3'd0 ;
  144.             end
  145.             5,6,7,8,9,10,11 : sta_bit <= sta_bit + uart_tx ;
  146.             21,22,23,24,25,26,27 : r_data[0] <= r_data[0] + uart_tx ;
  147.             37,38,39,41,42,43,44 : r_data[1] <= r_data[1] + uart_tx ; 
  148.             53,54,55,56,57,58,59 : r_data[2] <= r_data[2] + uart_tx ;
  149.             69,70,71,72,73,74,75 : r_data[3] <= r_data[3] + uart_tx ;
  150.             85,86,87,88,89,90,91 : r_data[4] <= r_data[4] + uart_tx ;
  151.             101,102,103,104,105,106,107 : r_data[5] <= r_data[5] + uart_tx ;
  152.             117,118,119,120,121,122,123 : r_data[6] <= r_data[6] + uart_tx ;
  153.             133,134,135,136,137,138,139 : r_data[7] <= r_data[7] + uart_tx ;
  154.             149,150,151,152,153,154,155 : sto_bit <= sto_bit + uart_tx ;
  155.             default ;
  156.         endcase
  157.     end
  158.  
  159.     always@( posedge clk or negedge reset )
  160.     begin
  161.         if ( ! reset )
  162.             rx_done_sig <= 8'd0 ;
  163.         else if ( ( bit16_cnt == 8'd159 ) && (div_cnt == bit_tim_16 - 2'd2 ) )//跑完159后产生一个rx_done信号
  164.             rx_done_sig <= 8'd1 ;
  165.         else if (rx_done_sig <= 8'd1 )
  166.             rx_done_sig <= 8'd0 ;
  167.     end         
  168.     
  169.     always@( posedge clk or negedge reset )//接收完数据发出rx_done
  170.     if(!reset )
  171.         rx_done <= 0 ;
  172.     else if (rx_done_sig)
  173.         rx_done <= 1 ;
  174.     else if (rx_done )
  175.         rx_done <= 0 ;
  176.     
  177.     
  178.     always@( posedge clk or negedge reset )//接收完数据发出rx_done后，把数据从r_data传递给data
  179.     begin
  180.         if ( ! reset )
  181.             data <= 8'd0 ;
  182.         else if ( rx_done_sig )
  183.         begin
  184.             data[0] = ( r_data[0] >3 ) ? 1 : 0 ;
  185.             data[1] = ( r_data[1] >3 ) ? 1 : 0 ;
  186.             data[2] = ( r_data[2] >3 ) ? 1 : 0 ;
  187.             data[3] = ( r_data[3] >3 ) ? 1 : 0 ;
  188.             data[4] = ( r_data[4] >3 ) ? 1 : 0 ;
  189.             data[5] = ( r_data[5] >3 ) ? 1 : 0 ;
  190.             data[6] = ( r_data[6] >3 ) ? 1 : 0 ;
  191.             data[7] = ( r_data[7] >3 ) ? 1 : 0 ;
  192.         end
  193. //        else if ( receive_en )
  194. //            data <= 8'd0 ;
  195.     end
  196.          
  197. endmodule

四、uart_to_ram模块

  1. module uart_to_ram(
  2.     clk ,
  3.     reset ,
  4.     data,
  5.     rx_done,
  6.     addr ,
  7.     dout ,
  8.     wenable    
  9.     );
  10.     
  11.     input clk ;
  12.     input reset ;
  13.     input [7:0]data;
  14.     input rx_done;
  15.     output reg [15:0]addr ;
  16.     output reg [15:0]dout ;
  17.     output reg wenable ;
  18.     
  19.     //ram的容量为256*256个像素，每个像素位宽16，共需256*256*2个8位的数据（131072）
  20.     //用计数器来计数
  21.     reg [16:0]pixel_cnt ;//131072
  22.     always@(posedge clk or negedge reset)
  23.     if(!reset)
  24.         pixel_cnt <= 17'd0 ;
  25.     else if ( ( pixel_cnt < 131071 ) && ( rx_done ) )
  26.         pixel_cnt <= pixel_cnt + 1 ;
  27.     else if (( pixel_cnt >= 131071 ) && ( rx_done ))
  28.         pixel_cnt <= 17'd0 ;
  29.    
  30.    //需要一个寄存器，存两个8位，共16位
  31.    reg [15:0]data_register ;
  32.    always@(posedge clk or negedge reset)
  33.     if(!reset)
  34.         data_register <= 16'd0 ;
  35.     else if ( rx_done  )
  36.         data_register <= { data_register[7:0] , data  } ;   
  37.    
  38.    //添加一个变化条件信号
  39.    reg change_sig ;
  40.    always@(posedge clk or negedge reset)
  41.     if(!reset)
  42.         change_sig <= 1'd0 ;
  43.     else if ( rx_done && ( pixel_cnt[0] == 1 )  )
  44.         change_sig <= 1'd1 ;
  45.     else if ( change_sig == 1'd1  )
  46.         change_sig <= 1'd0 ;
  47.     
  48.    //把每16位数据存进ram中，即输出16位数据
  49.     always@(posedge clk or negedge reset)
  50.     if(!reset)
  51.         dout <= 16'd0 ;
  52.     else if ( change_sig )
  53.         dout <= data_register ;
  54.     
  55.     //产生一个写入ram的使能信号
  56.     always@(posedge clk or negedge reset)
  57.     if(!reset)
  58.         wenable <= 0 ;
  59.     else if ( change_sig )
  60.         wenable <= 1 ;
  61.     else if (wenable == 1)
  62.         wenable <= 0 ;
  63.     
  64.     //产生写入ram的地址 //比weanbel和data提前变化，不然不满足下面除于2的条件，第0个地址将没有数据
  65.     always@(posedge clk or negedge reset)
  66.     if(!reset)
  67.         addr <= 16'd0 ;
  68.     else if (  rx_done && ( pixel_cnt[0] == 1 )  )
  69.         addr <= pixel_cnt[16:1] ; //除于2 即舍弃最后一位（右移一位）
  70.           
  71. endmodule

五、image_extract模块

  1. module image_extract
  2. #(
  3.   parameter H_Visible_area = 800, //整个屏幕显示区域宽度
  4.   parameter V_Visible_area = 480, //整个屏幕显示区域高度
  5.   parameter IMG_WIDTH      = 160, //图片宽度
  6.   parameter IMG_HEIGHT     = 120, //图片高度
  7.   parameter IMG_DATA_WIDTH = 16,  //图片像素点位宽
  8.   parameter ROM_ADDR_WIDTH = 16   //存储图片ROM的地址位宽
  9. )
  10. (
  11.   clk_ctrl,
  12.   reset_n,
  13.   img_disp_hbegin,
  14.   img_disp_vbegin,
  15.   disp_back_color,
  16.   Frame_Begin,
  17.   rom_addra,
  18.   rom_data,
  19.   disp_data_req,
  20.   visible_hcount,
  21.   visible_vcount,
  22.   disp_data
  23. );
  24.  
  25.   input                       clk_ctrl       ; //时钟输入，与TFT屏时钟保持一致
  26.   input                       reset_n        ; //复位信号，低电平有效
  27.  
  28.   input  [15:0]               img_disp_hbegin; //待显示图片左上角第一个像素点在TFT屏的行向坐标
  29.   input  [15:0]               img_disp_vbegin; //待显示图片左上角第一个像素点在TFT屏的场向坐标
  30.   input  [IMG_DATA_WIDTH-1:0] disp_back_color; //显示的背景颜色
  31.   
  32.   output [ROM_ADDR_WIDTH-1:0] rom_addra      ; //读图片数据ROM地址
  33.   input  [IMG_DATA_WIDTH-1:0] rom_data       ; //读图片数据ROM数据
  34.  
  35.   input                       Frame_Begin    ; //一帧图像起始标识信号，clk_ctrl时钟域
  36.   input                       disp_data_req  ; //
  37.   input  [11:0]               visible_hcount ; //TFT可见区域行扫描计数器
  38.   input  [11:0]               visible_vcount ; //TFT可见区域场扫描计数器
  39.   output [IMG_DATA_WIDTH-1:0] disp_data      ; //待显示图片数据
  40.   
  41.   reg   [ROM_ADDR_WIDTH-1:0]  rom_addra      ; //读图片数据rom地址 
  42.   
  43.   wire       h_exceed;
  44.   wire       v_exceed;
  45.   wire       img_h_disp;
  46.   wire       img_v_disp;
  47.   wire       img_disp;
  48.   wire [15:0]hcount_max;
  49.  
  50.   //判断设置的显示的起始位置是否会导致显示超出范围
  51.   assign h_exceed = img_disp_hbegin + IMG_WIDTH  > H_Visible_area - 1'b1;
  52.   assign v_exceed = img_disp_vbegin + IMG_HEIGHT > V_Visible_area - 1'b1;
  53.   //不同的设置情况，显示区域做不同的处理
  54.   assign img_h_disp = h_exceed ? (visible_hcount >= img_disp_hbegin && visible_hcount < H_Visible_area):
  55.                                  (visible_hcount >= img_disp_hbegin && visible_hcount < img_disp_hbegin + IMG_WIDTH);  
  56.   
  57.   assign img_v_disp = v_exceed ? (visible_vcount >= img_disp_vbegin && visible_vcount < V_Visible_area):
  58.                                  (visible_vcount >= img_disp_vbegin && visible_vcount < img_disp_vbegin + IMG_HEIGHT);
  59.      
  60.   assign img_disp = disp_data_req && img_h_disp && img_v_disp;
  61.   
  62.   assign hcount_max = h_exceed ? (H_Visible_area - 1'b1):(img_disp_hbegin + IMG_WIDTH - 1'b1);
  63.      
  64.   always@(posedge clk_ctrl or negedge reset_n)
  65.   begin
  66.     if(!reset_n)
  67.       rom_addra <= 'd0;
  68.     else if(Frame_Begin)
  69.       rom_addra <= 'd0; 
  70.     else if(img_disp)
  71.     begin
  72.       if(visible_hcount == hcount_max)
  73.         rom_addra <= rom_addra + (img_disp_hbegin + IMG_WIDTH - hcount_max);
  74.       else
  75.         rom_addra <= rom_addra + 1'b1;
  76.     end    
  77.     else
  78.       rom_addra <= rom_addra;
  79.   end
  81.   assign disp_data = img_disp ? rom_data : disp_back_color;
  83.  endmodule

六、disp_driver模块

  1. `include "disp_parameter_cfg.v"
  2.  
  3. module disp_driver(
  4.   ClkDisp,
  5.   Rst_p,
  6.  
  7.   Data,
  8.   DataReq,
  9.  
  10.   H_Addr,
  11.   V_Addr,
  12.  
  13.   Disp_HS,
  14.   Disp_VS,
  15.   Disp_Red,
  16.   Disp_Green,
  17.   Disp_Blue,
  18.   Frame_Begin,
  19.   Disp_DE,
  20.   Disp_PCLK
  21. );
  22.  
  23.   input ClkDisp;
  24.   input Rst_p;
  25.   input [`Red_Bits + `Green_Bits + `Blue_Bits - 1:0] Data;
  26.   output DataReq;
  27.  
  28.   output [11:0] H_Addr;
  29.   output [11:0] V_Addr;
  30.  
  31.   output reg Disp_HS;
  32.   output reg Disp_VS;
  33.  
  34.   output reg [`Red_Bits - 1 :0]Disp_Red;
  35.   output reg [`Green_Bits - 1 :0]Disp_Green;
  36.   output reg [`Blue_Bits - 1 :0]Disp_Blue;
  37.  
  38.   output reg Frame_Begin; //一帧图像起始标识信号，ClkDisp时钟域
  39.   output reg Disp_DE;
  40.   output Disp_PCLK;
  41.  
  42.   wire hcount_ov;
  43.   wire vcount_ov;
  44.  
  45.   //----------------内部寄存器定义----------------
  46.   reg [11:0] hcount_r;     //行扫描计数器
  47.   reg [11:0] vcount_r;     //场扫描计数器
  48.  
  49.   `ifdef HW_VGA
  50.     assign Disp_PCLK = ~ClkDisp;
  51.   `else
  52.     assign Disp_PCLK = ClkDisp;
  53.   `endif  
  54.  
  55.   assign DataReq = Disp_DE;
  56.  
  57.   parameter hdat_begin = `H_Sync_Time + `H_Back_Porch + `H_Left_Border - 1'b1;
  58.   parameter hdat_end = `H_Total_Time - `H_Right_Border - `H_Front_Porch - 1'b1;
  59.   
  60.   parameter vdat_begin  = `V_Sync_Time + `V_Back_Porch + `V_Top_Border - 1'b1;
  61.   parameter vdat_end = `V_Total_Time - `V_Bottom_Border - `V_Front_Porch - 1'b1;
  62.  
  63.   assign H_Addr = Disp_DE?(hcount_r - hdat_begin):12'd0;
  64.   assign V_Addr = Disp_DE?(vcount_r - vdat_begin):12'd0;
  65.  
  66.   //行扫描
  67.   assign hcount_ov = (hcount_r >= `H_Total_Time - 1);
  68.  
  69.   always@(posedge ClkDisp or posedge Rst_p)
  70.   if(Rst_p)
  71.     hcount_r <= 0;
  72.   else if(hcount_ov)
  73.     hcount_r <= 0;
  74.   else
  75.     hcount_r <= hcount_r + 1'b1;
  77.   //场扫描
  78.   assign vcount_ov = (vcount_r >= `V_Total_Time - 1);
  80.   always@(posedge ClkDisp or posedge Rst_p)
  81.   if(Rst_p)
  82.     vcount_r <= 0;
  83.   else if(hcount_ov) begin
  84.     if(vcount_ov)
  85.       vcount_r <= 0;
  86.     else
  87.       vcount_r <= vcount_r + 1'd1;
  88.   end
  89.   else
  90.     vcount_r <= vcount_r;
  91.  
  92.   always@(posedge ClkDisp)
  93.     Disp_DE <= ((hcount_r >= hdat_begin)&&(hcount_r < hdat_end))&&
  94.                ((vcount_r >= vdat_begin)&&(vcount_r < vdat_end));
  95.  
  96.   always@(posedge ClkDisp) begin
  97.     Disp_HS <= (hcount_r > `H_Sync_Time - 1);
  98.     Disp_VS <= (vcount_r > `V_Sync_Time - 1);
  99.     {Disp_Red,Disp_Green,Disp_Blue} <= (Disp_DE)?Data:1'd0;
  100.   end
  102.   /*******************************************/
  103.   reg Disp_VS_dly1;
  104.   always@(posedge ClkDisp)
  105.   begin
  106.     Disp_VS_dly1 <= Disp_VS;
  107.   end
  109.   always@(posedge ClkDisp or posedge Rst_p)
  110.   begin
  111.     if(Rst_p)
  112.       Frame_Begin <= 1'b0;
  113.     else if(!Disp_VS_dly1 && Disp_VS)
  114.       Frame_Begin <= 1'b1;
  115.     else
  116.       Frame_Begin <= 1'b0;
  117.   end
  118.   /*******************************************/
  119.  
  120. endmodule

七、disp_parameter_cfg.v参数配置文件

  1. /*使用说明
  2. 使用时根据实际工作需求选择2个预定义参数就可以
  3.  
  4. 参数1: MODE_RGBxxx
  5. 预定义用来决定驱动工作在16位模式还是24位模式，二选一
  6.   MODE_RGB888：24位模式
  7.   MODE_RGB565：16位模式
  8. 针对小梅哥提供的一系列显示设备，各个设备该参数的选择
  9.   4.3寸TFT显示屏------使用16位色RGB565模式
  10.   5寸TFT显示屏--------使用16位色RGB565模式
  11.   GM7123模块----------使用24位色RGB888模式
  12.  
  13. 参数2: Resolution_xxxx
  14. 预定义用来决定显示设备分辨率，常见设备分辨率如下所述
  15.  
  16. 4.3寸TFT显示屏：
  17.   Resolution_480x272
  18.  
  19. 5寸TFT显示屏：
  20.   Resolution_800x480
  21.  
  22. VGA常见分辨率：
  23.   Resolution_640x480
  24.   Resolution_800x600
  25.   Resolution_1024x600
  26.   Resolution_1024x768
  27.   Resolution_1280x720
  28.   Resolution_1920x1080
  29. */
  30.  
  31. //也可通过宏定义显示设备类型来进行设置，选择一个使能，其他使用注释的方式屏蔽
  32. //使用4.3寸480*272分辨率显示屏
  33. //`define HW_TFT43
  34.  
  35. //使用5寸800*480分辨率显示屏
  36. `define HW_TFT50
  37.  
  38. //使用VGA显示器，默认为640*480分辨率，24位模式，其他分辨率或需16位模式可在代码63行至75行进行重配置
  39. //`define HW_VGA
  40.  
  41. //=====================================
  42. //以下宏定义选择用于根据显示设备进行位模式和分辨率2个参数的设置
  43. //=====================================
  44. `ifdef HW_TFT43  //使用4.3寸480*272分辨率显示屏
  45.   `define MODE_RGB565
  46.   `define Resolution_480x272 1 //时钟为9MHz
  47.  
  48. `elsif HW_TFT50  //使用5寸800*480分辨率显示屏
  49.   `define MODE_RGB565
  50.   `define Resolution_800x480 1 //时钟为33MHz
  51.  
  52. `elsif HW_VGA    //使用VGA显示器，默认为640*480分辨率，24位模式
  53. //=====================================
  54. //可选择其他分辨率和16位模式，需用户根据实际需求设置
  55. //代码下方三行和四行设置位模式
  56. //代码下方五行以后连续宏定义部分设置分辨率
  57. //=====================================
  58.   `define MODE_RGB565
  59.  // `define MODE_RGB888
  60.   `define Resolution_640x480   1 //时钟为25.175MHz
  61.   //`define Resolution_800x600   1 //时钟为40MHz
  62.   //`define Resolution_1024x600  1 //时钟为51MHz
  63.   //`define Resolution_1024x768  1 //时钟为65MHz
  64.   //`define Resolution_1280x720  1 //时钟为74.25MHz
  65.   //`define Resolution_1920x1080 1 //时钟为148.5MHz
  66. `endif
  67.  
  68. //=====================================
  69. //非特殊需求，以下内容用户不需修改
  70. //=====================================
  71. //定义不同的颜色深度
  72. `ifdef MODE_RGB888
  73.   `define Red_Bits   8
  74.   `define Green_Bits 8
  75.   `define Blue_Bits  8
  76.   
  77. `elsif MODE_RGB565
  78.   `define Red_Bits   5
  79.   `define Green_Bits 6
  80.   `define Blue_Bits  5
  81. `endif
  82.  
  83. //定义不同分辨率的时序参数
  84. `ifdef Resolution_480x272
  85.   `define H_Total_Time    12'd525
  86.   `define H_Right_Border  12'd0
  87.   `define H_Front_Porch   12'd2
  88.   `define H_Sync_Time     12'd41
  89.   `define H_Back_Porch    12'd2
  90.   `define H_Left_Border   12'd0
  91.  
  92.   `define V_Total_Time    12'd286
  93.   `define V_Bottom_Border 12'd0
  94.   `define V_Front_Porch   12'd2
  95.   `define V_Sync_Time     12'd10
  96.   `define V_Back_Porch    12'd2
  97.   `define V_Top_Border    12'd0
  98.   
  99. `elsif Resolution_640x480
  100.   `define H_Total_Time    12'd800
  101.   `define H_Right_Border  12'd8
  102.   `define H_Front_Porch   12'd8
  103.   `define H_Sync_Time     12'd96
  104.   `define H_Back_Porch    12'd40
  105.   `define H_Left_Border   12'd8
  106.  
  107.   `define V_Total_Time    12'd525
  108.   `define V_Bottom_Border 12'd8
  109.   `define V_Front_Porch   12'd2
  110.   `define V_Sync_Time     12'd2
  111.   `define V_Back_Porch    12'd25
  112.   `define V_Top_Border    12'd8
  113.  
  114. `elsif Resolution_800x480
  115.   `define H_Total_Time    12'd1056
  116.   `define H_Right_Border  12'd0
  117.   `define H_Front_Porch   12'd40
  118.   `define H_Sync_Time     12'd128
  119.   `define H_Back_Porch    12'd88
  120.   `define H_Left_Border   12'd0
  121.  
  122.   `define V_Total_Time    12'd525
  123.   `define V_Bottom_Border 12'd8
  124.   `define V_Front_Porch   12'd2
  125.   `define V_Sync_Time     12'd2
  126.   `define V_Back_Porch    12'd25
  127.   `define V_Top_Border    12'd8
  128.  
  129. `elsif Resolution_800x600
  130.   `define H_Total_Time    12'd1056
  131.   `define H_Right_Border  12'd0
  132.   `define H_Front_Porch   12'd40
  133.   `define H_Sync_Time     12'd128
  134.   `define H_Back_Porch    12'd88
  135.   `define H_Left_Border   12'd0
  136.  
  137.   `define V_Total_Time    12'd628
  138.   `define V_Bottom_Border 12'd0
  139.   `define V_Front_Porch   12'd1
  140.   `define V_Sync_Time     12'd4
  141.   `define V_Back_Porch    12'd23
  142.   `define V_Top_Border    12'd0
  143.  
  144. `elsif Resolution_1024x600
  145.   `define H_Total_Time    12'd1344
  146.   `define H_Right_Border  12'd0
  147.   `define H_Front_Porch   12'd24
  148.   `define H_Sync_Time     12'd136
  149.   `define H_Back_Porch    12'd160
  150.   `define H_Left_Border   12'd0
  151.  
  152.   `define V_Total_Time    12'd628
  153.   `define V_Bottom_Border 12'd0
  154.   `define V_Front_Porch   12'd1
  155.   `define V_Sync_Time     12'd4
  156.   `define V_Back_Porch    12'd23
  157.   `define V_Top_Border    12'd0
  158.  
  159. `elsif Resolution_1024x768
  160.   `define H_Total_Time    12'd1344
  161.   `define H_Right_Border  12'd0
  162.   `define H_Front_Porch   12'd24
  163.   `define H_Sync_Time     12'd136
  164.   `define H_Back_Porch    12'd160
  165.   `define H_Left_Border   12'd0
  166.  
  167.   `define V_Total_Time    12'd806
  168.   `define V_Bottom_Border 12'd0
  169.   `define V_Front_Porch   12'd3
  170.   `define V_Sync_Time     12'd6
  171.   `define V_Back_Porch    12'd29
  172.   `define V_Top_Border    12'd0
  173.  
  174. `elsif Resolution_1280x720
  175.   `define H_Total_Time    12'd1650
  176.   `define H_Right_Border  12'd0
  177.   `define H_Front_Porch   12'd110
  178.   `define H_Sync_Time     12'd40
  179.   `define H_Back_Porch    12'd220
  180.   `define H_Left_Border   12'd0
  181.  
  182.   `define V_Total_Time    12'd750
  183.   `define V_Bottom_Border 12'd0
  184.   `define V_Front_Porch   12'd5
  185.   `define V_Sync_Time     12'd5
  186.   `define V_Back_Porch    12'd20
  187.   `define V_Top_Border    12'd0
  188.   
  189. `elsif Resolution_1920x1080
  190.   `define H_Total_Time    12'd2200
  191.   `define H_Right_Border  12'd0
  192.   `define H_Front_Porch   12'd88
  193.   `define H_Sync_Time     12'd44
  194.   `define H_Back_Porch    12'd148
  195.   `define H_Left_Border   12'd0
  196.  
  197.   `define V_Total_Time    12'd1125
  198.   `define V_Bottom_Border 12'd0
  199.   `define V_Front_Porch   12'd4
  200.   `define V_Sync_Time     12'd5
  201.   `define V_Back_Porch    12'd36
  202.   `define V_Top_Border    12'd0
  203.  
  204. `endif

八、IP配置

pll

rom_image

九、上板演示

上位机配置

发送数据

打开网盘中111.c，全选复制输入串口助手

点击发送

屏幕显示

声明：本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：【wpsshop博客】
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号